修改角色名脚本示范

[@main]
变更角色名条件：\
1、对于人物，需先退出行会、解除师徒及夫妻关系并需要收回元神。\
2、对于元神，需召唤出元神。\
<更换我的角色名/@修改角色名字> <更换元神的名字/@修改元神名字>\ \
<关闭/@exit>

[@修改角色名字]
#IF
TRUE
#ACT
QUERYVAL 20 0 14 @ChangeHumanName 请输入您要修改的名字：
break

[@ChangeHumanName]
#IF
HAVEGUILD
#ACT
SENDMSG 5 您目前拥有行会，无法使用更名系统...
break
#IF
CHECKMARRY
#ACT
SENDMSG 5 您目前暂未离婚，无法使用更名系统...
break
#IF
CHECKMASTER
#ACT
SENDMSG 5 您目前处于师徒状态，无法使用更名系统...
break
#IF
HAVEMASTER
#ACT
SENDMSG 5 您目前处于师徒状态，无法使用更名系统...
break
#IF
PneumaReleased
#ACT
SENDMSG 5 请收回您的元神
break
#IF
TRUE
#ACT
ChangeCharName $STR(S20)
break

;=====================================================

[@修改元神名字]
#IF
HasPneuma
#ACT
#ELSEACT
SENDMSG 5 您目前未拥有元神，无法使用更名系统...
break
#IF
!PneumaReleased
#ACT
SENDMSG 5 请释放您的元神
break
#IF
TRUE
#ACT
QUERYVAL 20 0 14 @ChangePneumaName 请输入您要修改元神的名字：
break

[@ChangePneumaName]
#IF
HasPneuma
#ACT
#ELSEACT
SENDMSG 5 您目前未拥有元神，无法使用更名系统...
break
#IF
!PneumaReleased
#ACT
SENDMSG 5 请释放您的元神
break
#IF
TRUE
#ACT
$PNEUMANAME.ChangeCharName $STR(S20)
break

;=====================================================

[@chgname_success]
成功！！！\ \
<关闭/@exit>\

[@chgname_fail_name_used]
修改失败，角色名已被使用\\
<关闭/@exit>\

[@chgname_fail_name_wrong_format]
修改失败，新角色名包含了过滤字符！\ \
<关闭/@exit>\

[@chgname_fail_no_character]
修改失败，查询不到角色！\ \
<关闭/@exit>\

[@chgname_fail_incomplete_data]
修改失败，数据错误！\ \
<关闭/@exit>\

[@chgname_fail_unknow]
修改失败，未知错误！\ \
<关闭/@exit>\